/*           CRTCMD     CMD(mylib/OPNDSPAPP) +                     */
/*                      PGM(QSYS/QUIOPNDA) +                       */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(OPNDSPAPP) +                        */
/*                      ALLOW( +                                   */
/*                        *IREXX +                                 */
/*                        *BREXX +                                 */
/*                        *BPGM +                                  */
/*                        *IPGM)                                   */

             CMD        PROMPT('Open UIM Display Application')
             PARM       KWD(APPHND) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        RTNVAL(*YES) +
                        MIN(1) +
                        PROMPT('Application handle     char(8)')
             PARM       KWD(PNLGRP) +
                        TYPE(Q00DD) +
                        MIN(1) +
                        CHOICE(*NONE) +
                        PROMPT('Panel group')
Q00DD:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        DFT(*LIBL) +
                        SPCVAL( +
                          (*CURLIB ) +
                          (*LIBL )) +
                        PROMPT('Panel group library')
             PARM       KWD(SCOPE) +
                        TYPE(*INT4) +
                        RSTD(*YES) +
                        DFT(*CALLER) +
                        SPCVAL( +
                          (*CALLER -1) +
                          (*JOB 0)) +
                        PROMPT('Application scope')
             PARM       KWD(EXIT) +
                        TYPE(*INT4) +
                        RSTD(*YES) +
                        DFT(*UNSTRUCT2) +
                        SPCVAL( +
                          (*STRUCT 0) +
                          (*UNSTRUCT1 1) +
                          (*UNSTRUCT2 2)) +
                        PROMPT('Exit parameter interface')
             PARM       KWD(HELPSIZE) +
                        TYPE(*CHAR) +
                        LEN(1) +
                        RSTD(*YES) +
                        DFT(*WINDOW) +
                        SPCVAL( +
                          (*FULL Y) +
                          (*WINDOW N)) +
                        PROMPT('Help display area')
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)