/*           CRTCMD     CMD(mylib/GETLSTE) +                       */
/*                      PGM(QSYS/QUIGETLE) +                       */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(GETLSTE) +                          */
/*                      ALLOW( +                                   */
/*                        *IREXX +                                 */
/*                        *BREXX +                                 */
/*                        *BPGM +                                  */
/*                        *IPGM)                                   */

             CMD        PROMPT('Get UIM List Entry')
             PARM       KWD(APPHND) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        MIN(1) +
                        PROMPT('Application handle')
             PARM       KWD(VARBUF) +
                        TYPE(*CHAR) +
                        LEN(128) +
                        RTNVAL(*YES) +
                        MIN(1) +
                        PROMPT('Variable buffer      char(128)')
             PARM       KWD(VARBUFLEN) +
                        TYPE(*INT4) +
                        DFT(128) +
                        RANGE( +
                          1 +
                          128) +
                        PROMPT('Variable buffer length')
             PARM       KWD(VARRCDNAM) +
                        TYPE(*NAME) +
                        LEN(10) +
                        PASSVAL(*NULL) +
                        PROMPT('Variable record name')
             PARM       KWD(LSTNAM) +
                        TYPE(*NAME) +
                        LEN(10) +
                        PASSVAL(*NULL) +
                        PROMPT('List name')
             PARM       KWD(POSOPT) +
                        TYPE(*CHAR) +
                        LEN(4) +
                        RSTD(*YES) +
                        DFT(*NEXT) +
                        SPCVAL( +
                          (*FIRST FRST) +
                          (*LAST LAST) +
                          (*NEXT NEXT) +
                          (*PRV PREV) +
                          (*BOT BOT) +
                          (*TOP TOP) +
                          (*FIRSTSLT FSLT) +
                          (*HNDL HNDL) +
                          (*LASTSLT LSLT) +
                          (*NEXTSLT NSLT) +
                          (*PRVSLT PSLT) +
                          (*SAME SAME)) +
                        PROMPT('Entry location option')
             PARM       KWD(CPYOPT) +
                        TYPE(*CHAR) +
                        LEN(1) +
                        RSTD(*YES) +
                        DFT(*YES) +
                        SPCVAL( +
                          (*YES Y) +
                          (*NO N)) +
                        PROMPT('Copy values option')
             PARM       KWD(SLTCTA) +
                        TYPE(Q027A) +
                        CHOICE(*NONE) +
                        PROMPT('Selection criteria')
Q027A:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        RSTD(*YES) +
                        DFT(*DFT) +
                        SPCVAL( +
                          (*EQUAL EQ) +
                          (*NEQUAL NE) +
                          (*GREATER GT) +
                          (*LESS LT) +
                          (*GEQUAL GE) +
                          (*LEQUAL LE) +
                          (*DFT EQ))
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        PROMPT('Variable to compare against')
             PARM       KWD(SLTHND) +
                        TYPE(*CHAR) +
                        LEN(4) +
                        PROMPT('Selection handle')
             PARM       KWD(EXTOPT) +
                        TYPE(*CHAR) +
                        LEN(4) +
                        RSTD(*YES) +
                        DFT(*NO) +
                        SPCVAL( +
                          (*YES Y) +
                          (*NO N)) +
                        PROMPT('Extend-list option')
             PARM       KWD(LSTEHND) +
                        TYPE(*CHAR) +
                        LEN(4) +
                        RTNVAL(*YES) +
                        PROMPT('List entry handle      char(4)')
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)