/*           CRTCMD     CMD(mylib/DSPHLPPNL) +                     */
/*                      PGM(QSYS/QUHDSPH) +                        */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(DSPHLPPNL) +                        */
/*                      TEXT('Display help panel') +               */
/*                      ALLOW( +                                   */
/*                        *IREXX +                                 */
/*                        *IPGM +                                  */
/*                        *EXEC +                                  */
/*                        *INTERACT)                               */

             CMD        PROMPT('Display a help panel')
             PARM       KWD(HLPIDARY) +
                        TYPE(Q00AB) +
                        MIN(1) +
                        CHOICE(*NONE) +
                        PROMPT('Qualified help panel name')
Q00AB:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        DFT(*LIBL) +
                        SPCVAL( +
                          (*CURLIB ) +
                          (*LIBL )) +
                        PROMPT('Help ID panel library')
             QUAL       TYPE(*CHAR) +
                        LEN(32) +
                        DFT(NONE) +
                        PROMPT('Help ID module name')
             PARM       KWD(NBRHLPIDS) +
                        TYPE(*INT4) +
                        CONSTANT(1)
             PARM       KWD(HLPTYP) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(X'0000000100000001')
             PARM       KWD(HLPTTL) +
                        TYPE(*CHAR) +
                        LEN(55) +
                        CONSTANT('Help panel display')
             PARM       KWD(HLPIDXSCH) +
                        TYPE(*CHAR) +
                        LEN(20) +
                        CONSTANT(*NONE)
             PARM       KWD(HLPDSPTYP) +
                        TYPE(*CHAR) +
                        LEN(1) +
                        RSTD(*YES) +
                        DFT(*WINDOW) +
                        SPCVAL( +
                          (*WINDOW N) +
                          (*FULL Y)) +
                        PROMPT('Window or full-screen?')
             PARM       KWD(HLPUPRLFT) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(X'0000001400000007')
             PARM       KWD(HLPLWRRGT) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(X'000000150000004F')
             PARM       KWD(HLPCSRLOC) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(X'000000140000001D')
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)