/*           CRTCMD     CMD(mylib/DLTUSRIDXE) +                    */
/*                      PGM(QSYS/QUSRMVUI) +                       */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(DLTUSRIDXE) +                       */
/*                      TEXT('QUSRMVUI -- Interactive')            */

             CMD        PROMPT('Delete User Index Entry')
             PARM       KWD(NBRENTRMV) +
                        TYPE(*INT4) +
                        CONSTANT(0)
             PARM       KWD(ENTRMV) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(X'0000000000000000')
             PARM       KWD(ENTRMVLEN) +
                        TYPE(*INT4) +
                        CONSTANT(0)
             PARM       KWD(ENTLENOFFS) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(X'0000000000000000')
             PARM       KWD(ELOLEN) +
                        TYPE(*INT4) +
                        CONSTANT(0)
             PARM       KWD(USRIDXLIBR) +
                        TYPE(*CHAR) +
                        LEN(10) +
                        CONSTANT(*NONE)
             PARM       KWD(USRIDX) +
                        TYPE(Q01FB) +
                        CHOICE(*NONE) +
                        PROMPT('User index name')
Q01FB:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        DFT(*LIBL) +
                        SPCVAL( +
                          (*CURLIB ) +
                          (*LIBL )) +
                        PROMPT('Index library')
             PARM       KWD(FORMAT) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        CONSTANT(IDXE0100)
             PARM       KWD(MAXENT) +
                        TYPE(*INT4) +
                        DFT(*MIN) +
                        RANGE( +
                          1 +
                          4095) +
                        SPCVAL( +
                          (*MAX 4095) +
                          (*MIN 1)) +
                        PROMPT('Maximum number of entries')
             PARM       KWD(RMVTYPE) +
                        TYPE(*INT4) +
                        RSTD(*YES) +
                        DFT(*EQ) +
                        SPCVAL( +
                          (*EQ 1) +
                          (*GT 2) +
                          (*LT 3) +
                          (*GE 4) +
                          (*LE 5) +
                          (*FIRST 6) +
                          (*LAST 7) +
                          (*BETWEEN 8)) +
                        PROMPT('Remove type')
             PARM       KWD(RMVCRIT) +
                        TYPE(*CHAR) +
                        LEN(2000) +
                        EXPR(*YES) +
                        PASSVAL(*NULL) +
                        PROMPT('Remove criteria')
             PARM       KWD(RMVCRITLEN) +
                        TYPE(*INT4) +
                        DFT(120) +
                        RANGE( +
                          1 +
                          1000) +
                        PROMPT('Length of remove criteria')
             PARM       KWD(RMVCTAOFFS) +
                        TYPE(*INT4) +
                        DFT(120) +
                        RANGE( +
                          1 +
                          1000) +
                        PROMPT('Remove criteria offset')
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)
             DEP        CTL(*ALWAYS) +
                        PARM( +
                          (RMVCRIT)) +
                        MSGID(SYU5020)
/* +
             ADDMSGD    MSGID(SYU5020) MSGF(mylib/mymsgf) +
                          MSG('RMVCRIT is unspecified. Enter a +
                          value to insert.') SECLVL('There was no +
                          value specified for the remove criteria +
                          (RMVCRIT) parameter. If no value is +
                          specified, nothing can be removed. +
                          Specify a value for the parameter and +
                          retry the command.') +
*/