/*           CRTCMD     CMD(mylib/ADDUSRIDXE) +                    */
/*                      PGM(QSYS/QUSADDUI) +                       */
/*                      SRCFILE(mylib/mysrc) +                     */
/*                      SRCMBR(ADDUSRIDXE) +                       */
/*                      TEXT('QUSADDUI')                           */

             CMD        PROMPT('Add User Index Entry')
             PARM       KWD(RETLIB) +
                        TYPE(*CHAR) +
                        LEN(10) +
                        CONSTANT(' ') +
                        MIN(1)
             PARM       KWD(NBRENTADD) +
                        TYPE(*INT4) +
                        CONSTANT(0) +
                        MIN(1)
             PARM       KWD(USRIDX) +
                        TYPE(Q011B) +
                        MIN(1) +
                        CHOICE(*NONE) +
                        PROMPT('Qualified user index name' 1)
Q011B:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        DFT(*LIBL) +
                        SPCVAL( +
                          (*CURLIB ) +
                          (*LIBL )) +
                        PROMPT('Index library')
             PARM       KWD(INSTYPE) +
                        TYPE(*INT4) +
                        RSTD(*YES) +
                        DFT(*UNIQUE) +
                        SPCVAL( +
                          (*UNIQUE 1) +
                          (*REPLACE 2) +
                          (*NOREPLACE 3)) +
                        PMTCTL(*PMTRQS) +
                        PROMPT('Insert type' 4)
             PARM       KWD(IDXENTRY) +
                        TYPE(*CHAR) +
                        LEN(2000) +
                        EXPR(*YES) +
                        PROMPT('Index entry' 2)
             PARM       KWD(ENTLEN) +
                        TYPE(*INT4) +
                        DFT(120) +
                        RANGE( +
                          1 +
                          2000) +
                        PROMPT('User index entry length' 3)
             PARM       KWD(ENTLENOFFS) +
                        TYPE(Q0285) +
                        CHOICE(*NONE)
Q0285:       QUAL       TYPE(*NAME) +
                        LEN(4) +
                        CONSTANT(NONE)
             QUAL       TYPE(*INT4) +
                        CONSTANT(0)
             PARM       KWD(NBRENT) +
                        TYPE(*INT4) +
                        CONSTANT(1)
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)
             DEP        CTL(*ALWAYS) +
                        PARM( +
                          (IDXENTRY)) +
                        MSGID(SYU5010)

/* +
             ADDMSGD    MSGID(SYU5010) MSGF(mylib/mymsgf) +
                          MSG('IDXENTRY is unspecified. Enter a +
                          value to insert.') SECLVL('There was no +
                          value specified for the index entry +
                          (IDXENTRY) parameter. If no value is +
                          specified, nothing can be inserted. +
                          Specify a value for the parameter and +
                          retry the command.') +
*/