/*           CRTCMD     CMD(mylib/ADDUIEVAR) +                     */
/*                      PGM(QSYS/QUSADDUI) +                       */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(ADDUIEVAR) +                        */
/*                      TEXT('QUSADDUI')                           */

             CMD        PROMPT('Add User Index Variable Entry')
             PARM       KWD(RETLIB) +
                        TYPE(*CHAR) +
                        LEN(10) +
                        CONSTANT(' ') +
                        MIN(1)
             PARM       KWD(NBRENTADD) +
                        TYPE(*INT4) +
                        CONSTANT(0) +
                        MIN(1)
             PARM       KWD(USRIDX) +
                        TYPE(Q011B) +
                        MIN(1) +
                        CHOICE(*NONE) +
                        PROMPT('Qualified user index name' 1)
Q011B:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        DFT(*LIBL) +
                        SPCVAL( +
                          (*CURLIB ) +
                          (*LIBL )) +
                        PROMPT('Index library')
             PARM       KWD(INSTYPE) +
                        TYPE(*INT4) +
                        RSTD(*YES) +
                        DFT(*UNIQUE) +
                        SPCVAL( +
                          (*UNIQUE 1) +
                          (*REPLACE 2) +
                          (*NOREPLACE 3)) +
                        PMTCTL(*PMTRQS) +
                        PROMPT('Insert type' 5)
             PARM       KWD(IDXENTRY) +
                        TYPE(*CHAR) +
                        LEN(2000) +
                        EXPR(*YES) +
                        PROMPT('Index entry' 2)
             PARM       KWD(ENTLEN) +
                        TYPE(*INT4) +
                        DFT(120) +
                        RANGE( +
                          1 +
                          2000) +
                        PROMPT('User index entry length' 3)
             PARM       KWD(ENTLENOFFS) +
                        TYPE(*CHAR) +
                        LEN(8) +
                        FULL(*YES) +
                        EXPR(*YES) +
                        PROMPT('Length/offset hex pair char(8)' 4)
             PARM       KWD(NBRENT) +
                        TYPE(*INT4) +
                        CONSTANT(1)
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)
             DEP        CTL(*ALWAYS) +
                        PARM( +
                          (IDXENTRY)) +
                        MSGID(SYU5010)
             DEP        CTL(*ALWAYS) +
                        PARM( +
                          (ENTLENOFFS)) +
                        MSGID(SYU5030)
/* +
   See ADDUSRIDXE for SYU5010 +
*/
/* +
             ADDMSGD    MSGID(SYU5030) MSGF(mylib/mymsgf) +
                          MSG('ENTLENOFFS is unspecified. Enter a +
                          value to insert.') SECLVL('There was no +
                          value specified for the entry length and +
                          offset (ENTLENOFFS) parameter. If no +
                          value is specified, a variable length +
                          entry cannot be processed. Specify a +
                          value for the parameter consisting of a +
                          char(8) data element made of two +
                          binary(4) concatenated data elements and +
                          retry the command.') +
*/