/*           CRTCMD     CMD(mylib/VFYSPL) +                        */
/*                      PGM(mylib/VFYSPL) +                        */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(VFYSPL) +                           */
/*                      ALLOW( +                                   */
/*                        *IREXX +                                 */
/*                        *IPGM +                                  */
/*                        *EXEC +                                  */
/*                        *INTERACT)                               */

             CMD        PROMPT('Verify Spelling')
             PARM       KWD(WORD) +
                        TYPE(*CHAR) +
                        LEN(256) +
                        MIN(1) +
                        EXPR(*YES) +
                        VARY(*YES) +
                        PROMPT('Word to spell-check' 1)
             PARM       KWD(WRDLEN) +
                        TYPE(*DEC) +
                        LEN(3 0) +
                        DFT(0) +
                        RANGE( +
                          1 +
                          256) +
                        PMTCTL(*PMTRQS) +
                        PROMPT('Word length' 4)
             PARM       KWD(VFYOPT) +
                        TYPE(*LGL) +
                        LEN(1) +
                        RSTD(*YES) +
                        DFT(*VERIFY) +
                        SPCVAL( +
                          (*VERIFY '0') +
                          (*SUGGEST '1')) +
                        PROMPT('Verify option' 2)
             PARM       KWD(SUGGESTOPT) +
                        TYPE(*LGL) +
                        LEN(1) +
                        RSTD(*YES) +
                        DFT(*MISSPELL) +
                        SPCVAL( +
                          (*ALL '1') +
                          (*MISSPELL '0')) +
                        PMTCTL(P018D) +
                        PROMPT('Suggestion option' 3)
P018D:       PMTCTL     CTL(VFYOPT) +
                        COND( +
                          (*EQ '1'))