/*           CRTCMD     CMD(mylib/SNDBRKMSGB) +                    */
/*                      PGM(QSYS/QEZSNDMG) +                       */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(SNDBRKMSGB) +                       */
/*                      TEXT('QZLSENDS Send break message (ass+    */
/*                      isted)') +                                 */
/*                      ALLOW( +                                   */
/*                        *IREXX +                                 */
/*                        *BREXX +                                 */
/*                        *BPGM +                                  */
/*                        *IPGM)                                   */

             CMD        PROMPT('Send break message (assisted)')
             PARM       KWD(MSGTYP) +
                        TYPE(*CHAR) +
                        LEN(10) +
                        RSTD(*YES) +
                        DFT(*INFO) +
                        VALUES( +
                          '*INQ' +
                          '*INFO') +
                        PROMPT('Message type')
             PARM       KWD(DLVRY) +
                        TYPE(*CHAR) +
                        LEN(10) +
                        RSTD(*YES) +
                        DFT(*BREAK) +
                        VALUES( +
                          '*BREAK' +
                          '*NORMAL') +
                        PROMPT('Delivery mode')
             PARM       KWD(MSG) +
                        TYPE(*CHAR) +
                        LEN(494) +
                        EXPR(*YES) +
                        PROMPT('Message text')
             PARM       KWD(MSGLEN) +
                        TYPE(*INT4) +
                        DFT(*MAX) +
                        SPCVAL( +
                          (*MAX 494) +
                          (*MIN 0)) +
                        EXPR(*YES) +
                        PROMPT('Message text length')
             PARM       KWD(RCP) +
                        TYPE(*CHAR) +
                        LEN(1000) +
                        EXPR(*YES) +
                        PROMPT('Recipients')
             PARM       KWD(NBRRCP) +
                        TYPE(*INT4) +
                        EXPR(*YES) +
                        PROMPT('Number of recipients')
             PARM       KWD(MSGSNT) +
                        TYPE(*CHAR) +
                        LEN(4) +
                        RTNVAL(*YES) +
                        PROMPT('Message sent indicator')
             PARM       KWD(FUNC) +
                        TYPE(*CHAR) +
                        LEN(4) +
                        RTNVAL(*YES) +
                        PROMPT('Function requested')
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)