/********************************************************************/
/*  Process a command against each entry on a list of objects.      */
/********************************************************************/
/*           CRTCMD     CMD( mylib/PRCOBJLST ) +                    */
/*                      PGM( mylib/PRCOBJLST ) +                    */
/*                      SRCFILE( mylib/mysrcf ) +                   */
/*                      SRCMBR( PRCOBJLST ) +                       */
/*                      TEXT( 'Process object list' ) +             */
/*                      PRDLIB( mylib )                             */

 PRCOBJLST:  CMD        PROMPT('Process cmd against an OBJLST')

/*------------------------------------------------------------------*/


/*                                                                  */
/*    CMD:  The command string; may contain substitution values...  */
/*        @@O = the object name is substituted here...              */
/*        @@L = the library name is substituted here...             */
/*        @@T = the object type is substituted here...              */
/*              (@@T prohibited by command prompter)                */
/*                                                                  */
             PARM       KWD(CMD) TYPE(*CMDSTR) LEN(6000) MIN(1) +
                          VARY(*YES *INT2) PROMPT('Command')

/*                                                                  */
/*    LST: The name of the list...                                  */
/*                                                                  */
             PARM       KWD(LST) TYPE(*NAME) LEN(10) DFT(*FIRST) +
                          SPCVAL((*FIRST)) PROMPT('List name')


/*                                                                  */
/*    LSTF: The file the list is held in...                         */
/*                                                                  */
             PARM       KWD(LSTF) TYPE(QLSTF) PMTCTL(*PMTRQS) +
                          PROMPT('List file')

 QLSTF:      QUAL       TYPE(*NAME) LEN(10) DFT(*DFT) SPCVAL((*DFT))
             QUAL       TYPE(*NAME) LEN(10) DFT(QTEMP) +
                          SPCVAL((*LIBL) (*CURLIB)) PROMPT('Library')


/*                                                                  */
/*    PRCERR: Process continues if errors found?                    */
/*                                                                  */
             PARM       KWD(PRCERR) TYPE(*CHAR) LEN(4) RSTD(*YES) +
                          DFT(*YES) VALUES(*YES *NO) +
                          PMTCTL(*PMTRQS) PROMPT('Process errors?')


/*                                                                  */
/*    ERRACT: Action to take if errors found?                       */
/*                                                                  */
             PARM       KWD(ERRACT) TYPE(*CHAR) LEN(10) RSTD(*YES) +
                          DFT(*CONTINUE) VALUES(*CONTINUE) +
                          PMTCTL(*PMTRQS) PROMPT('Error action')