/********************************************************************/
/*  Build a list of files to process a command against              */
/********************************************************************/
/*           CRTCMD     CMD( mylib/BLDFLST ) +                       */
/*                      PGM( mylib/BLDFLST ) +                       */
/*                      SRCFILE( mylib/mysrcf ) +                    */
/*                      SRCMBR( BLDFLST ) +                          */
/*                      TEXT( 'Build a list of files' ) +            */
/*                      PRDLIB( mylib )                              */

 BLDFLST:    CMD        PROMPT('Build a list of files')


/*                                                                  */
/*    FILE: The files to list, by name...                           */
/*                                                                  */
             PARM       KWD(FILE) TYPE(QFILE) MIN(1) PROMPT('File' 1)

 QFILE:      QUAL       TYPE(*GENERIC) LEN(10) SPCVAL((*ALL)) MIN(1)
             QUAL       TYPE(*NAME) LEN(10) DFT(*USRLIBL) +
                          SPCVAL((*LIBL) (*CURLIB) (*USRLIBL) +
                          (*ALLUSR) (*ALL)) PROMPT('Library')


/*                                                                  */
/*    FILEATR: Attribute selection -- kind of file...               */
/*                                                                  */
             PARM       KWD(FILEATR) TYPE(*CHAR) LEN(5) RSTD(*YES) +
                          DFT(*ALL) VALUES(*ALL *DSPF *PRTF *DKTF +
                          *TAPF *CMNF *BSCF *MXDF *PF *LF *SAVF +
                          *DDMF *ICFF) PROMPT('File attributes')


/*                                                                  */
/*    LSTF: The file the list is held in...                         */
/*                                                                  */
             PARM       KWD(LSTF) TYPE(QLSTF) PMTCTL(*PMTRQS) +
                          PROMPT('List file' 3)

 QLSTF:      QUAL       TYPE(*NAME) LEN(10) DFT(*DFT) SPCVAL((*DFT))
             QUAL       TYPE(*NAME) LEN(10) DFT(QTEMP) +
                          SPCVAL((*LIBL) (*CURLIB)) PROMPT('Library')


/*                                                                  */
/*    LSTOPT: List 'options'...                                     */
/*                                                                  */
             PARM       KWD(LSTOPT) TYPE(ELSTOPT) PMTCTL(*PMTRQS) +
                          PROMPT('List options' 2)

/*            A name for the list...                                */
 ELSTOPT:    ELEM       TYPE(*NAME) LEN(10) DFT(*FILE) +
                          SPCVAL((*FILE) (*FIRST)) PROMPT('List name')

/*            Add or replace...                                     */
             ELEM       TYPE(*CHAR) LEN(8) RSTD(*YES) DFT(*REPLACE) +
                          VALUES(*REPLACE *ADD) PROMPT('Replace or +
                          add to list')