BLDOBJLST:  PGM        PARM(&QOBJ &QOBJTYP &QLSTF &ELSTOPT)


             DCL        VAR(&QOBJ) TYPE(*CHAR) LEN(20)
             DCL        VAR(&QOBJTYP) TYPE(*CHAR) LEN(10)
             DCL        VAR(&QLSTF) TYPE(*CHAR) LEN(20)
             DCL        VAR(&ELSTOPT) TYPE(*CHAR) LEN(20)


             DCL        VAR(&OBJ) TYPE(*CHAR) LEN(10)
             DCL        VAR(&OBJLIB) TYPE(*CHAR) LEN(10)

             DCL        VAR(&OBJTYP) TYPE(*CHAR) LEN(10)

             DCL        VAR(&LSTF) TYPE(*CHAR) LEN(10)
             DCL        VAR(&LSTFLIB) TYPE(*CHAR) LEN(10)

             DCL        VAR(&LSTNAM) TYPE(*CHAR) LEN(10)
             DCL        VAR(&LSTOPT) TYPE(*CHAR) LEN(8)


             DCL        VAR(&WRKLEN) TYPE(*DEC) LEN(5)


             MONMSG     MSGID(CPF0000 CPF9999) EXEC(GOTO +
                          CMDLBL(STDERR))


             CHGVAR     VAR(&OBJ) VALUE(%SST(&QOBJ 1 10))
             CHGVAR     VAR(&OBJLIB) VALUE(%SST(&QOBJ 11 10))

             IF         COND(&OBJ *EQ *IBM *OR &OBJ *EQ *ALLUSR) +
                          THEN(DO)
             CHGVAR     VAR(&OBJLIB) VALUE('*N')
             ENDDO


             CHGVAR     VAR(&OBJTYP) VALUE(&QOBJTYP)


             CHGVAR     VAR(&LSTF) VALUE(%SST(&QLSTF 1 10))
             CHGVAR     VAR(&LSTFLIB) VALUE(%SST(&QLSTF 11 10))

             IF         COND(&LSTF *EQ '*DFT') THEN(RTVDTAARA +
                          DTAARA(SYLSTOBJ) RTNVAR(&LSTF))


             CHGVAR     VAR(&LSTNAM) VALUE(%SST(&ELSTOPT 3 10))
             CHGVAR     VAR(&LSTOPT) VALUE(%SST(&ELSTOPT 13 8))


             IF         COND(&LSTNAM *EQ '*OBJ') THEN(DO)

             CHGVAR     VAR(&LSTNAM) VALUE(&OBJ)

             IF         COND(&LSTNAM *EQ '*ALL') THEN(CHGVAR +
                          VAR(&LSTNAM) VALUE('#ALL'))

             ELSE       CMD(DO)

             RTNLEN     VALUE(&OBJ) LEN(&WRKLEN)

             IF         COND(%SST(&OBJ &WRKLEN 1) *EQ '*') THEN(DO)
             CHGVAR     VAR(&WRKLEN) VALUE(&WRKLEN - 1)
             CHGVAR     VAR(&LSTNAM) VALUE(%SST(&OBJ 1 &WRKLEN))
             ENDDO

             ENDDO

             ENDDO


             DSPOBJD    OBJ(&OBJLIB/&OBJ) OBJTYPE(&OBJTYP) +
                          OUTPUT(*OUTFILE) OUTFILE(&LSTFLIB/&LSTF) +
                          OUTMBR(&LSTNAM &LSTOPT)


             RETURN

 STDERR:     MOVDIAGMSG
             MONMSG     MSGID(CPF0000 MCH0000)
             RSNESCMSG
             MONMSG     MSGID(CPF0000 MCH0000)

             ENDPGM