/*           CRTCMD     CMD(mylib/CHKDTAQKE) +                     */
/*                      PGM(QSYS/QMHRDQM) +                        */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(CHKDTAQKE) +                        */
/*                      ALLOW( +                                   */
/*                        *BPGM +                                  */
/*                        *IPGM)                                   */

             CMD        PROMPT('Check Dtaq Keyed Entry')
             PARM       KWD(RCVQFLD) +
                        TYPE(*CHAR) +
                        LEN(2322) +
                        RTNVAL(*YES) +
                        MIN(1) +
                        PROMPT('Entry return variable' 2)
             PARM       KWD(RCVQFLDLEN) +
                        TYPE(*INT4) +
                        RANGE( +
                          8 +
                          2322) +
                        MIN(1) +
                        PROMPT('Returned data length' 3)
             PARM       KWD(FORMAT) +
                        TYPE(*NAME) +
                        LEN(8) +
                        CONSTANT(RDQM0100) +
                        MIN(1)
             PARM       KWD(DTAQ) +
                        TYPE(Q0152) +
                        MIN(1) +
                        CHOICE(*NONE) +
                        PROMPT('Dtaq name' 1)
Q0152:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        DFT(*LIBL) +
                        SPCVAL( +
                          (*CURLIB ) +
                          (*LIBL )) +
                        PROMPT('Library')
             PARM       KWD(MSI) +
                        TYPE(*CHAR) +
                        LEN(272) +
                        MIN(1) +
                        PROMPT('Message selection info' 5)
             PARM       KWD(MSILEN) +
                        TYPE(*INT4) +
                        DFT(32) +
                        RANGE( +
                          17 +
                          272) +
                        PROMPT('Message selection info length' 6)
             PARM       KWD(MSIFORMAT) +
                        TYPE(*NAME) +
                        LEN(8) +
                        CONSTANT(RDQS0200)
             PARM       KWD(ERRCOD) +
                        TYPE(*INT4) +
                        CONSTANT(0)