/*           CRTCMD     CMD(mylib/RTVSPLFAST) +                    */
/*                      PGM(QSYS/QUSRSPLA) +                       */
/*                      SRCFILE(mylib/mysrcf) +                    */
/*                      SRCMBR(RTVSPLFAST) +                       */
/*                      TEXT('QUSRSPLA') +                         */
/*                      ALLOW( +                                   */
/*                        *IREXX +                                 */
/*                        *BREXX +                                 */
/*                        *BPGM +                                  */
/*                        *IPGM)                                   */

             CMD        PROMPT('Retrieve *splf attr struct')
             PARM       KWD(SPLFA) +
                        TYPE(*CHAR) +
                        LEN(1142) +
                        RTNVAL(*YES) +
                        MIN(1) +
                        PROMPT('Attributes structure')
             PARM       KWD(STRUCLEN) +
                        TYPE(*INT4) +
                        CONSTANT(1142) +
                        MIN(1)
             PARM       KWD(FORMATNAM) +
                        TYPE(*NAME) +
                        LEN(8) +
                        CONSTANT(SPLA0100) +
                        MIN(1)
             PARM       KWD(JOB) +
                        TYPE(Q0161) +
                        SNGVAL( +
                          (* )) +
                        MIN(1) +
                        PROMPT('Qualified job name')
Q0161:       QUAL       TYPE(*NAME) +
                        LEN(10) +
                        MIN(1) +
                        EXPR(*YES)
             QUAL       TYPE(*NAME) +
                        LEN(10) +
                        EXPR(*YES) +
                        PROMPT('Job user')
             QUAL       TYPE(*CHAR) +
                        LEN(6) +
                        RANGE( +
                          '000000' +
                          '999999') +
                        EXPR(*YES) +
                        PROMPT('Job number')
             PARM       KWD(INTJOBID) +
                        TYPE(*CHAR) +
                        LEN(16) +
                        CONSTANT('                ') +
                        MIN(1)
             PARM       KWD(INTSPLFID) +
                        TYPE(*CHAR) +
                        LEN(16) +
                        CONSTANT('                ') +
                        MIN(1)
             PARM       KWD(SPLFNAM) +
                        TYPE(*NAME) +
                        LEN(10) +
                        MIN(1) +
                        EXPR(*YES) +
                        PROMPT('*SPLF name')
             PARM       KWD(SPLFNBR) +
                        TYPE(*INT4) +
                        DFT(*LAST) +
                        RANGE( +
                          -1 +
                          9999) +
                        SPCVAL( +
                          (*ONLY 0) +
                          (*LAST -1)) +
                        EXPR(*YES) +
                        PROMPT('*SPLF number')