/**************************************************
 *
 * sign35.pov
 *
 * POV-Ray source for Dealey Plaza Sign
 * and Lamppost study.
 *
 * For POV-Ray 3.5
 *
 * By Joe Durnavich
 * 11/12/03
 *
 **************************************************/

#include "colors.inc"
#include "shapes.inc"
#include "metals.inc" 
#include "woods.inc"
#include "stones.inc"


global_settings
{
        ambient_light 5
} 



/**************************************************
 *
 * Camera definitions
 *
 **************************************************/

/* 
 * The cameras are setup to use the right-handed coordinate system.
 * This allows the use of coordinate values that closely resemble
 * the coordinates on John Hunt's HSCA map.  Coordinates here are in
 * feet, so divide the x and y values on the map by 10 to get feet.
 * Also, make the y value negative.
 *
 */

#declare Barnes_camera = camera
{
        up    <0, 1, 0>
        
        // To generate images with the right aspect ratio, put the pixel width
        // and height ratio in the "right" statement and also remember to set
        // this Width and Height in the .INI file.
        right  <-1406/1086, 0, 0>  

        // Angle is the field of view in degrees.
        angle 58.8                 

        // Sky orients the camera.
        // Put tan of camera roll angle in y. 
        sky <0, tan(radians(1.9)), 1>              // 1.9 deg CCW

        // Move the camera to our model pedestal.
        location <133.5, -153.3, 106.35>

        // Look east.
        look_at <264.0, -170.65, 95.36> 
}

#declare Plan_view = camera
{
        orthographic
        up <0, 1, 0>
        right <-4/3, 0, 0>    
        angle 1.0
        sky <0, 0, 1>         
        location<188.6, -152.7, 10000> 
        look_at<188.6, -152.7, 92.8> 
}

#declare Zapruder_Z193_view = camera
{
        up <0, 1, 0>
        right <-465/349, 0, 0>          // David Wimp's distortion corrected frames
        angle 10.2
        sky <0, tan(radians(-0.8)), 1>  // 0.8 deg CW
        location<136.4, -154.2, 106.2> 
        look_at <305.5, -145.82, 97.82>
}

#declare Zapruder_Z228_view = camera
{
        up <0, 1, 0>
        right <-465/349, 0, 0>  
        angle 10.2
        sky <0, tan(radians(-1.9)), 1>  
        location<136.3, -154.4, 106.25> 
        look_at <289.4, -169.47, 95.32>
}

#declare Zapruder_Z263_view = camera
{
        up <0, 1, 0>
        right <-465/349, 0, 0>
        angle 10.2
        sky <0, tan(radians(-3.8)), 1> 
        location<135.5, -155.3, 106.25> 
        look_at <185.6, -174.18, 101.465>
}

#declare ZapBarnes_Barnes_loc = camera
{
        up <0, 1, 0>
        right <-465/349, 0, 0> 
        angle 10.2
        sky <0, tan(radians(-0.8)), 1>
        location<133.5, -153.3, 106.35>  
        look_at <305.5, -146.82, 97.82>
}



/**************************************************
 *
 * Dealey Plaza object and marker definitions
 *
 **************************************************/

#declare Lamppost = union
{
        cylinder {<185.8, -177.9, 90.3> <185.6, -177.95, 103.966>, 0.15}
        pigment {Green}
}

#declare Column = union
{
        box
        {
                <329.0, -149.6, 98.7>
                <333.8, -144.6, 114.4>
                texture {T_Grnt1} 
                // finish {ambient 0.25}
        }

        // Vertical wall corner marker
        cylinder {<313.1, -158.8, 97.4> <313.1, -158.8, 103.1>, 0.1}
        
        // Horizontal wall segment marker
        cylinder {<313.1, -158.8, 103.1> <313.2, -240.1, 103.3>, 0.1}
       
        // Left edge of left set of holes
        cylinder {<313.055, -181.079, 97.4> <313.055, -181.079, 103.1>, 0.1}

        // Right edge of right set of holes
        cylinder {<313.161, -223.4, 97.4> <313.161, -223.4, 103.3>, 0.1}
        cylinder {<313.1, -214.07, 101.0> <313.161, -223.4, 101.0>, 0.1}
        
        pigment {Green} 
}

#declare Houston_Buildings_Markers = union
{
        cylinder {<451.2, -104.6, 100.5> <451.2, -104.6, 195>, 0.25}
        cylinder {<451.0, -185.9, 100.5> <451.0, -185.9, 195>, 0.25}
        cylinder {<449.7, -214.7, 100.5> <449.7, -214.7, 220>, 0.25}
        cylinder {<449.4, -305.5, 100.5> <449.4, -305.5, 220>, 0.25}
        pigment {Green}
}

#declare Sign = box
{
        <-4.0, 0.05, -2.0>
        <4.0,  -0.05, 2.0>   
        texture {T_Wood10}
}

#declare Sign_Pole = cylinder
{
        <0, 0, 5.0>, <0, 0, -4.6>, 0.09375  
        open
        texture {T_Silver_1B}
}


#declare Stemmons_Sign = union
{
        object {Sign}

        // Uncomment this section to get a right sign pole.
        //object
        //{
        //        Sign_Pole
        //        translate <3.025, -0.11875, -2.85>
        //}

        rotate <0, 2.4, -54.5>
        translate <0, 0, 7.8>
        translate <187.6, -152.7, 92.8>       
}

#declare Pedestal = union
{
        box
        {
                <-4/3, -2.0, -2.0>
                <4/3, 2.0, 2.0>
        }
        
        box
        {
                <-1.2708, -1.9375, -0.2>
                <1.2708, 1.9375, 0.2>  
                translate <0, 0, 2.2>
        }

        texture {T_Grnt1} 


}



/**************************************************
 *
 * Objects
 *
 **************************************************/

object {Pedestal}
object {Lamppost}
object {Stemmons_Sign}  
object {Column}
object {Houston_Buildings_Markers}  



/**************************************************
 *
 * Lights and camera selection
 *
 **************************************************/

light_source
{
	<0, -10000, 100>  
	color White 
	rotate <-36.973, 0, -4.896>
}

camera
{
        /*
         * Uncomment one of these for the view from that position.
         * Also remember to set the right Width and Height in your INI file.
         * When you select Run, image will also write to the sign.bmp file.
         */

        Barnes_camera
        // Plan_view        
        // Zapruder_Z193_view
        // Zapruder_Z228_view 
        // Zapruder_Z263_view 
        // ZapBarnes_Barnes_loc 
}